酷我音乐 破解脚本

https://www.52pojie.cn/thread-1274972-1-1.html

@ECHO OFF &CD /D "%\~DP0"&NET SESSION>NUL 2>&1||(ECHO 请以管理员身份运行 &PAUSE>NUL&EXIT)

taskkill /f /im KwMusic* >NUL 2>NUL
taskkill /f /im KwService* >NUL 2>NUL
taskkill /f /im KwWebKit* >NUL 2>NUL
taskkill /f /im KwWallpaper* >NUL 2>NUL

rd/s/q "%temp%\KWMUSIC" 2>NUL
del/f/s/q "%temp%\kuwo*" >NUL 2>NUL
del/f/s/q "%temp%\KwBindApp*" >NUL 2>NUL

rd/s/q "%ProgramData%\Kuwodata" 2>NUL
rd/s/q "%AllUsersProfile%\Application Data\Kuwodata" 2>NUL
reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /f /v "kwmusic" >NUL 2>NUL
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /f /v "kwmusic" >NUL 2>NUL
reg delete "HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Run" /f /v "kwmusic" >NUL 2>NUL

ver|findstr "5\.[0-9]\.[0-9][0-9]*" >NUL && (
md "%AllUsersProfile%\Application Data\kuwodata\kwmusic2013\ModuleData\ModMusicTool" 2>NUL
echo f|copy /y "Bin\Data\conf.txt" "%AllUsersProfile%\Application Data\kuwodata\kwmusic2013\ModuleData\ModMusicTool" >NUL 2>NUL
echo y|icacls "%AllUsersProfile%\Application Data\kuwodata\kwmusic2013\ModuleData\ModMusicTool\conf.txt" /c /grant "Everyone:(R,RX)" /inheritance:r >NUL 2>NUL
echo. >"%AllUsersProfile%\Application Data\kuwodata\kwmusic2013\ModuleData\ModNotify" 2>NUL
echo. >"%AllUsersProfile%\Application Data\kuwodata\kwmusic2013\Update" 2>NUL
echo. >"%AllUsersProfile%\Application Data\kuwodata\kwshow" 2>NUL
)
ver|findstr "\<6\.[0-9]\.[0-9][0-9]*\> \<10\.[0-9]\.[0-9][0-9]*\>" >NUL && (
md "%ProgramData%\Kuwodata\kwmusic2013\ModuleData\ModMusicTool" 2>NUL
echo f|copy /y "Bin\Data\conf.txt" "%ProgramData%\Kuwodata\kwmusic2013\ModuleData\ModMusicTool" >NUL 2>NUL
echo y|icacls "%ProgramData%\kuwodata\kwmusic2013\ModuleData\ModMusicTool\conf.txt" /c /grant "Everyone:(R,RX)" /inheritance:r >NUL 2>NUL
echo. >"%ProgramData%\kuwodata\kwmusic2013\ModuleData\ModNotify" 2>NUL
echo. >"%ProgramData%\kuwodata\kwmusic2013\Update" 2>NUL
echo. >"%ProgramData%\kuwodata\kwshow" 2>NUL
)

reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\AppCompatFlags\Layers" /f /v "%\~dp0KwMusic.exe" /d "\~ RUNASADMIN" >NUL 2>NUL

mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(a.SpecialFolders(""Desktop"") & ""\酷我音乐.lnk""):b.TargetPath=""%\~dp0KwMusic.exe"":b.WorkingDirectory=""%\~dp0"":b.Save:close")

CLS&ECHO.&ECHO 完成！
ECHO.&ECHO 创建听歌识曲快捷方式到桌面？
ECHO.&ECHO 是敲下任意键；否关闭窗口呗！&PAUSE>NUL

mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(a.SpecialFolders(""Desktop"") & ""\听歌识曲.lnk""):b.TargetPath=""%\~dp0bin\KwKnowSong.exe"":b.WorkingDirectory=""%\~dp0"":b.Save:close")

CLS&ECHO.&ECHO 完成！&PAUSE>NUL&EXIT